home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 011 / flips12.arc / FLIPSCON.BAS < prev    next >
Encoding:
BASIC Source File  |  1986-04-17  |  8.2 KB  |  190 lines
  1. 1000 ' COMPILER COMMANDS:
  2. 1010 '                      $TITLE:    '> FLIPS < Configurator  John Intorcio'
  3. 1020 '                      $SUBTITLE: 'VER 1.2  April 17, 1986'
  4. 1030 CLS
  5. 1040 PRINT "      ╔══════════════════════════════════════════════════╗"
  6. 1050 PRINT "      ║            > F L I P S <   Ver. 1.2              ║"
  7. 1060 PRINT "      ║                                                  ║"
  8. 1070 PRINT "      ║  This program is distributed as user supported   ║"
  9. 1080 PRINT "      ║  software.  You are free to copy and distribute  ║"
  10. 1090 PRINT "      ║  this program provided:                          ║"
  11. 1100 PRINT "      ║                                                  ║"
  12. 1110 PRINT "      ║      1. It is not distributed in modified form.  ║"
  13. 1120 PRINT "      ║      2. No fee or consideration is charged.      ║"
  14. 1130 PRINT "      ║      3. This message is not bypassed or removed. ║"
  15. 1140 PRINT "      ║                                                  ║"
  16. 1150 PRINT "      ║   If you run this program and find it usefull    ║"
  17. 1160 PRINT "      ║   and if you would like to make a contribution   ║"
  18. 1170 PRINT "      ║   toward the development of future versions or   ║"
  19. 1180 PRINT "      ║   if you discover problems or fixes write to:    ║"
  20. 1190 PRINT "      ║                                                  ║"
  21. 1200 PRINT "      ║            John Intorcio                         ║"
  22. 1210 PRINT "      ║            247 State Stret                       ║"
  23. 1220 PRINT "      ║            Northampton, MA  01060                ║"
  24. 1230 PRINT "      ║                                                  ║"
  25. 1240 PRINT "      ║   Or contact <The ToolBox> at (617) 364-2474     ║"
  26. 1250 PRINT "      ╚══════════════════════════════════════════════════╝"
  27. 1260 DIM COMM.PORTS$(5)
  28. 1270 PAUSE.TIME=4:GOSUB 2200
  29. 1280 '
  30. 1290 ' ------ READ IN CONFIG FILE IF IT EXISTS ------
  31. 1300 '
  32. 1310 GOSUB 2340
  33. 1320 '
  34. 1330 ' ------ MAIN MENU ------
  35. 1340 '
  36. 1350 ON ERROR GOTO 0
  37. 1360 CLS
  38. 1370 PRINT "         F L I P S Configurator  Ver. 1.2"
  39. 1380 PRINT
  40. 1390 PRINT "1.  Bulletin Board Name. . . . . . . . . . . .  ";BOARD.NAME$
  41. 1400 PRINT "2.  Welcome Screen File Name . . . . . . . . .  ";WELCOME.SCR$
  42. 1410 PRINT "3.  Path for Welcome Screen. . . . . . . . . .  ";WEL.PATH$
  43. 1420 PRINT "4.  Name for RBBS-PC Message File. . . . . . .  ";MSG.FILE$
  44. 1430 PRINT "5.  Path for RBBS-PC Message File. . . . . . .  ";MSG.PATH$
  45. 1440 PRINT "6.  Instructions File Name . . . . . . . . . .  ";HELP.FILE$
  46. 1450 PRINT "7.  Path for Instruction File. . . . . . . . .  ";HLP.PATH$
  47. 1460 PRINT "8.  Line Feed Default (1=Y, 0=N) . . . . . . . ";LF.FLAG
  48. 1470 PRINT "9.  Graphics Default (1=ASCII, 0=None) . . . . ";GRAPHICS.FLAG
  49. 1480 PRINT "10. Maximum Games per Session. . . . . . . . . ";MAX.GAMES
  50. 1490 PRINT "11. Maximum Time per Session (Min) . . . . . . ";MAX.TIME
  51. 1500 PRINT "12. Communications Port for Node 1. . . . . .  ";COMM.PORTS$(1)
  52. 1510 PRINT "13. Communications Port for Node 2. . . . . .  ";COMM.PORTS$(2)
  53. 1520 PRINT "14. Communications Port for Node 3. . . . . .  ";COMM.PORTS$(3)
  54. 1530 PRINT "15. Communications Port for Node 4. . . . . .  ";COMM.PORTS$(4)
  55. 1540 PRINT "16. Communications Port for Node 5. . . . . .  ";COMM.PORTS$(5)
  56. 1550 PRINT "17. Pause After Computer Moves (Sec) . . . . . ";COMP.MOVE.PAUSE
  57. 1560 PRINT "18. Allow Return Users . . . . . . . . . . . . ";ALLOW.RETURN.USER$
  58. 1570 PRINT
  59. 1580 PRINT
  60. 1590 INPUT "   Option to Change (0 to Exit) ";OPT
  61. 1600 '
  62. 1610 ' --------- BRANCH ON OPT --------
  63. 1620 '
  64. 1630 IF OPT=0 THEN 1990
  65. 1640 ON OPT GOTO 1650,1670,1690,1710,1730,1750,1770,1790,1810,1830,1850,1870,1870,1870,1870,1870,1920,1940,1360
  66. 1650 CLS:LINE INPUT "Bulletin Board Name ? ";BOARD.NAME$
  67. 1660 GOTO 1360
  68. 1670 CLS:LINE INPUT "Welcome Screen File ? ";WELCOME.SCR$
  69. 1680 GOTO 1360
  70. 1690 CLS:LINE INPUT "Path for Welcome Screen ? ";WEL.PATH$
  71. 1700 GOTO 1360
  72. 1710 CLS:LINE INPUT "Name for RBBS-PC Message File ? ";MSG.FILE$
  73. 1720 GOTO 1360
  74. 1730 CLS:LINE INPUT "Path for RBBS-PC Message File ? ";MSG.PATH$
  75. 1740 GOTO 1360
  76. 1750 CLS:LINE INPUT "Instruction File Name ? ";HELP.FILE$
  77. 1760 GOTO 1360
  78. 1770 CLS:LINE INPUT "Path for Instruction File ? ";HLP.PATH$
  79. 1780 GOTO 1360
  80. 1790 IF LF.FLAG=0 THEN LF.FLAG=1 ELSE LF.FLAG=0
  81. 1800 GOTO 1360
  82. 1810 IF GRAPHICS.FLAG=0 THEN GRAPHICS.FLAG=1 ELSE GRAPHICS.FLAG=0
  83. 1820 GOTO 1360
  84. 1830 CLS:INPUT "Maximum Games per Session ";MAX.GAMES
  85. 1840 GOTO 1360
  86. 1850 CLS:INPUT "Maximum Minutes per Session ";MAX.TIME
  87. 1860 GOTO 1360
  88. 1870 TEMP = OPT - 11
  89. 1880 CLS:PRINT "Comm port for Node";TEMP;"(Form: COMx:, Default is NONE) ";
  90. 1890 INPUT COMM.PORTS$(TEMP)
  91. 1900 IF COMM.PORTS$(TEMP) = "" THEN COMM.PORTS$(TEMP) = "NONE"
  92. 1910 GOTO 1360
  93. 1920 CLS:INPUT "Seconds to Pause After Computer's Move ";COMP.MOVE.PAUSE
  94. 1930 GOTO 1360
  95. 1940 IF ALLOW.RETURN.USER$="YES" THEN ALLOW.RETURN.USER$="NO" ELSE ALLOW.RETURN.USER$="YES"
  96. 1950 GOTO 1360
  97. 1960 '
  98. 1970 ' -------   WRITE FILE ------
  99. 1980 '
  100. 1990 OPEN "FLIPS.CNF" FOR OUTPUT AS #2
  101. 2000 PRINT #2, BOARD.NAME$
  102. 2010 PRINT #2, WELCOME.SCR$
  103. 2020 PRINT #2, WEL.PATH$
  104. 2030 PRINT #2, MSG.FILE$
  105. 2040 PRINT #2, MSG.PATH$
  106. 2050 PRINT #2, HELP.FILE$
  107. 2060 PRINT #2, HLP.PATH$
  108. 2070 PRINT #2, LF.FLAG
  109. 2080 PRINT #2, GRAPHICS.FLAG
  110. 2090 PRINT #2, MAX.GAMES
  111. 2100 PRINT #2, MAX.TIME
  112. 2110 PRINT #2, COMM.PORTS$(1)
  113. 2120 PRINT #2, COMM.PORTS$(2)
  114. 2130 PRINT #2, COMM.PORTS$(3)
  115. 2140 PRINT #2, COMM.PORTS$(4)
  116. 2150 PRINT #2, COMM.PORTS$(5)
  117. 2160 PRINT #2, COMP.MOVE.PAUSE
  118. 2170 PRINT #2, ALLOW.RETURN.USER$
  119. 2180 CLOSE #2:SYSTEM
  120. 2190 '
  121. 2200 ' --- PAUSE LOOP ----
  122. 2210 ' --- LENGTH OF PAUSE IN SECONDS IS PASSSED AS PAUSE.TIME
  123. 2220 ' --- USES TIME SINCE MIDNIGHT SO WILL GET SCREWED UP
  124. 2230 ' --- IF RUNNING WHEN ROLLOVER OCCURS
  125. 2240 '
  126. 2250 TIME.PASSED=0:START.TIME$=TIME$
  127. 2260 START.SECONDS=VAL(MID$(START.TIME$,1,2))*3600+VAL(MID$(START.TIME$,4,2))*60+VAL(MID$(START.TIME$,7,2))
  128. 2270 WHILE TIME.PASSED<PAUSE.TIME
  129. 2280 NOW.TIME$=TIME$
  130. 2290 NOW.SECONDS=VAL(MID$(NOW.TIME$,1,2))*3600+VAL(MID$(NOW.TIME$,4,2))*60+VAL(MID$(NOW.TIME$,7,2))
  131. 2300 TIME.PASSED=NOW.SECONDS-START.SECONDS
  132. 2310 WEND
  133. 2320 RETURN
  134. 2330 '
  135. 2340 ' --- SUBROUTINE TO READ CONFIGURATION FILE
  136. 2350 '
  137. 2360 ' CONFIG FILE ASSUMED TO BE TEXT FILE WITH ONE ENTRY PER LINE
  138. 2370 ' VARIABLES ASSUMED LISTED IN THE FOLLOWING ORDER:
  139. 2380 '
  140. 2390 ' BOARD.NAME$           NAME OF BULLETIN BOARD TO BE LISTED
  141. 2400 ' WELCOME.SCR$          PATH AND FILE NAME FOR WELCOME SCREEN
  142. 2410 ' WEL.PATH$             PATH TO FIND WELCOME SCREEN FILE
  143. 2420 ' MSG.FILE$             NAME FOR MESSAGE PATH
  144. 2430 ' MSG.PATH$             PATH TO FIND MESSAGE FILE
  145. 2440 ' HLP.PATH$             PATH TO FIND INSTRUCTION FILE
  146. 2450 ' LF.FLAG               DEFAULT LINE FEED SETTING: 1 IF YES, 0 IF NO
  147. 2460 ' GRAPHICS.FLAG         DEFAULT GRAPHICS SETTING: 1 IF ASCII, 0 IF NONE
  148. 2470 ' MAX.GAMES             MAXIMUM GAMES A PLAYER IS ALLOWED
  149. 2480 ' MAX.TIME              MAXIMUM TIME IN MINUTES A PLAYER MAY SPEND
  150. 2490 ' COMM.PORTS$(1)        \ 
  151. 2500 ' COMM.PORTS$(2)         \
  152. 2510 ' COMM.PORTS$(3)          >  COMM PORTS FOR NODES
  153. 2520 ' COMM.PORTS$(4)         /   1 THROUGH 5
  154. 2530 ' COMM.PORTS$(5)        / 
  155. 2540 ' COMP.MOVE.PAUSE       PAUSE TIME AFTER COMPUTER'S MOVE
  156. 2550 ' ALLOW.RETURN.USER$    WHETHER RETURN USERS ARE ALLOWED
  157. 2560 '
  158. 2570 ' ----- SET UP FOR FILE NOT FOUND ERROR -----
  159. 2580 ON ERROR GOTO 2830
  160. 2590 ' ------- OPEN FILE
  161. 2600 OPEN "FLIPs.CNF" FOR INPUT AS #2
  162. 2610 ' ------ RESET ERRORS ------
  163. 2620 ON ERROR GOTO 0
  164. 2630 ' ------ READ FILE
  165. 2640 LINE INPUT #2, BOARD.NAME$
  166. 2650 LINE INPUT #2, WELCOME.SCR$
  167. 2660 LINE INPUT #2, WEL.PATH$
  168. 2670 LINE INPUT #2, MSG.FILE$
  169. 2680 LINE INPUT #2, MSG.PATH$
  170. 2690 LINE INPUT #2, HELP.FILE$
  171. 2700 LINE INPUT #2, HLP.PATH$
  172. 2710 INPUT #2, LF.FLAG
  173. 2720 INPUT #2, GRAPHICS.FLAG
  174. 2730 INPUT #2, MAX.GAMES
  175. 2740 INPUT #2, MAX.TIME
  176. 2750 LINE INPUT #2, COMM.PORTS$(1)
  177. 2760 LINE INPUT #2, COMM.PORTS$(2)
  178. 2770 LINE INPUT #2, COMM.PORTS$(3)
  179. 2780 LINE INPUT #2, COMM.PORTS$(4)
  180. 2790 LINE INPUT #2, COMM.PORTS$(5)
  181. 2800 INPUT #2, COMP.MOVE.PAUSE
  182. 2810 LINE INPUT #2, ALLOW.RETURN.USER$
  183. 2820 CLOSE #2:RETURN
  184. 2830 '
  185. 2840 ' ------- TRAP FOR CONFIG FILE NOT FOUND ------
  186. 2850 '
  187. 2860 PRINT "      FLIPS.CNF Not Found!!!!  OK to Create ([Y] or N)";:INPUT RSP$
  188. 2870 IF RSP$="n" OR RSP$="N" THEN SYSTEM
  189. 2880 RESUME 1330
  190.